Phân tích liên kết cạnh tranh: Link Intersect trong Excel
Không có bất cứ nghi ngờ nào nữa, 1 trong những bước chính để tạo nên 1 chiến lược SEO chính là phân tích cạnh tranh. Các backlink của các đối thủ cạnh tranh giúp cung cấp thông tin cho chiến lược xây dựng liên kết của họ cũng như giúp bạn có cơ hội để củng cố thêm profile liên kết.

Những cơ hội này rất khó để xác định mà nắm bắt bằng các cách thủ công, đặc biệt là ở các nơi các website thường muốn sở hữu 1 lượng backlink khổng lồ. Mặc dù đã có các công cụ hỗ trợ để trợ giúp cho việc này, như Moz Link Intersect, nhưng tôi đã chọn Excel bởi vì tôi nghĩ rằng nó sẽ cung cấp sự linh hoạt hơn trong việc xử lí dữ liệu.

Và tôi đã viết bản hướng dẫn dưới đây để giải thích cho các bạn hiểu hơn về cách bạn có thể xây dựng các phân tích liên kết cạnh tranh của mình trong Excel, bao gồn cả 1 bản mẫu để các bạn có thể bắt đầu tự thực hiện được ngay lập tức.

Chính xác thì 1 Link Intersect là gì?

Như bạn đã biết, công cụ Moz Link Intersect (hay còn được gọi là Công cụ nghiên cứu liên kết cạnh tranh hay công cụ tìm kiếm liên kết cạnh tranh), cùng với các công cụ khác cùng loại với nó, giúp bạn để tìm thấy các tiên miền mà liên kết tới các đối thủ cạnh tranh của bạn mà không liên kết tới bạn. Vì vậy bạn có thể tìm ra rất nhiều cơ hội cho để sở hữu liên kết đặc biết với những tên miền mà liên kết tới nhiều hơn 1 trong số các đối thủ cạnh tranh của bạn bởi vì như vậy bạn sẽ có cơ hội cao hơn để họ liên kết tới bạn.

Công cụ này của Moz hiện giờ không còn khả dụng nhưng tôi tin nó sẽ trở lại vào 1 ngày không xa. Bản Excel cũng là 1 công cụ tương tự, nó cho phép bạn xem được tên miền mà liên kết tới các đối thủ cạnh tranh của bạn, và chính xác URL nào mà họ đang dùng để liên kết đến chúng. Hơn thế nữa, nó còn giúp bạn biết được các thông số khác mà có thể giúp bạn biết liên kết nào nên để kết nối.

Tại sao tôi lại cần đến bản Excel?
Dưới đây là những thuận lợi khi sử dụng Excel so với các công cụ khác.
- Thứ nhất, hầu hết các công cụ giúp bạn có cơ hội sở hữu liên kết thì đều yêu cầu thuê bao hàng tháng.
- Thứ hai, nếu bạn chỉ có 1 doanh nghiệp SEO nhỏ như tôi , và không có đủ tiền để xây dựng 1 công cụ của riêng mình, thì Excel là chính 1 trong những công cụ hữu ích nhất. Nó sẽ là sự lựa chọn lí tưởng cho việc phân tích dữ liệu và quan sát cũng như sở hữu rất nhiều các Plugin thuận tiện có thêt giúp đỡ bạn rất nhiều trong công việc làm SEO hàng ngày. Hơn thế nữa, các dữ liệu được xuất ra từ nó cũng được đưa tới 1 địa điểm thống nhất.
- Thứ ba, bản Excel còn giúp bạn để:
+ Sử dụng các dữ liệu backlink từ bất kì nhà cung cấp nào, miễn là nó có Source URL (nơi liên kết được post) và 1 Target URL (nơi liên kết hướng tới), tất nhiên là bất kì thông số nào cũng cho ta biết được 1 điều gì đó nhưng bạn nên chọn lọc để phù hợp với mục đích của mình.
+ Phân loại dữ liệu theo cách bạn cần, theo số lượng các đối thủ cạnh tranh mà các liên kết hướng tơi hoặc theo các thông số.
Phân tích càng nhiều về các đối thủ cạnh tranh càng tốt miễm là máy tính của bạn có thể xử lí được hết.

Làm được nó và bạn đã hoàn thành rồi

Ok, nếu bạn vẫn theo cách chỉ dẫn của tôi, tôi tin là bạn sẽ thích nó. Vậy tôi sẽ giải thích từng bước các cách để tạo ra nó. Nó bao gồm 1 bảng chính không quá khó để sử dụng, và tôi sẽ dùng ảnh chụp màn hình để hiển thị cách thực hiện nó cho bạn.

Nếu bạn muốn bỏ qua các bước tới đây để xem kết quả cuối cùng, hãy kéo xuống luôn mục:Mẫu và các hướng dẫn sử dụng.

Các công cụ để chuyển đổi
Trước khi cúng ta bắt đầu, bạn cần biết các điều dưới đây:
- Bạn có thể bị shock bởi công cụ này nhưng bạn sẽ rất cần nó để làm công việc này ☺ Tôi đã sử dụng bạn 32bit của năm 2010 ở ví dụ của tôi.
- Dữ liệu Backlink. Bạn có thể sử dụng Moz OSE, Ahref’s Site Explorer, Majestic SEO’s Site Explorer, hay bất cứ công cụ nào đáp ứng được các yêu cầu tôi đã đề cập bên trên. Và có khả năng để xuất ra Excel. Ví dụ, tôi đã từng sử dụng OSE.
- 6-8 giờ thời gian làm việc của bạn. Tôi đùa đấy ☺

Bước 1: Xuất dữ liệu Backlink của bạn
Đây là 1 điều khá cơ bản. Neus bạn đã từng sử dụng OSE cho phân tích Backlink trước đây, bạn hoàn toàn có thể biết là việc này dễ dàng. Cá nhân tôi có 1 tài khoản ở Moz PRO vì vậy tôi đang dùng OSE cho bước này.

Vì tôi vừa mới cho ra mắt website công ty tôi nên tôi sẽ không sử dụng nó làm ví dụ. Ngoài ra tôi cũng không có thời gian để chọn ra 1 website tiêu biểu nên tôi sẽ dùng luôn Seomoz.org làm website chính.

Tôi sẽ chọn 3 đối thủ cạnh tranh là: distilled.net, seerinteractive.com and seogadget.co.uk .

Lấy dữ liệu backlink từ những website này (bao gồm cả website chính Seomoz.org) là 1 điều đơn giản. Đến OSE nhập tên miền và nhấn ‘’SEARCH’’. Tiếp theo, bạn sẽ lọc các kết quả tìm kiếm để gắn các liên kết tới các trang theo tên miền chính hoặc phụ.



Chú ý quan trọng: Gắn các liên kết và tên miền chính thường lấy được nhiều dữ liệu hơn nhưng bạn sẽ phải sử dụng thêm 2 công thức ở BƯỚC 3

Bạn có thể lọc kĩ hơn để chỉ lấy các liên kết dofollow. Chỉ cần chắc chắn rằng bạn sẽ nhấn vào nút ‘’Filter’’.
Tiếp theo, bạn cần tải các liên kết này và OSE sẽ cho bạn 2 sự lựa chọn. Hoặc bạn sử dụng nút ‘’Download CSV’’ và nhận được ngay 10000 liên kết hoặc sử dụng mô-đun Advanced Reports – nơi bạn chỉ nhận được 1 lượng liên kết giới hạn hàng ngày nhưng tổng vào bạn sẽ có khoảng 100k liên kết.

Trong trường hợp này bạn nên chọn "External linking page" và "Any page on this root domain". Mặc dù bạn có thể lọc với mức DA/PA cao hơn 1 mức cố định để giảm các kết quả tìm kiếm liên kết nhưng dường như điều này cũng không có nhiều tác dụng.



Lưu ý rằng bạn có thể xuất liên tiếp các dữ liệu chứ không cần đợi cái này xong rồi mới tiếp tực đến cái tiếp theo. Bạn sẽ nhận được email khi việc xuất dữ liệu hoàn thành.

Cuối cùng nữa là chúng ta nên có 4 file CSV khác nhau (1 cho dữ liệu backlink của chúng ta, 3 cho các đối thủ cạnh trạnh của chúng ta)

Bước 2: Nhập nó vào Excel
Đã tới lúc của phần mềm ‘’kì diệu’’- Excel.
Để lấy dữ liệu từ cac file CSV, chúng ta có 2 sự lựa chọn:
- Hoặc mở các file CSV trực tiếp, copy các cột chúng ta thấy cần( nên là cột URL, Target URL và bất kì thông số nào bạn cần nữa) vào sao đó Paste chúng vào 1 Worksheet mới.
- Hoặc sử dụng Excel Text Import để nhập luôn dữ liệu vào các Worksheet trống mà không cần mở các file CSV

Cả 2 lựa chọn trên đều khá đơn giản.Mặc dù lựa chọn thứ nhất dễ nhất thực hiện hơn nhưng có 1 trở ngại rằng nó sẽ không hoạt động được nếu Window máy tính cảu bạn đươc cài ở Châu Âu.

Điều này là bởi vì các file CSV đều có dấu phẩy mà dấu phẩy lại là dấu cách mặc định của người Mĩ. Trong khi với các nước Châu Âu thì dấu cách mặc định lại là dấu chấm phẩy. Điều này dẫn đên việc Excel sẽ không đọc được file CSV 1 cách chính xác.

Để giải quyết được vấn để này, bạn cần mở tùy chọn ‘’Regional and Language’’ ở mục Contro Panel trong Window và chỉnh lại thành tiếng anh (English).

Ngoài ra còn có khả năng thứ 2 đó là do cách Excel của bạnh nhập dữ liệu. Một trong số các dữ liệu đã bị hiển thị sai và chúng ta sẽ phải chỉnh sửa lại dữ liệu bằng cách loại bỏ tất cả các lỗi này. Tôi không có đủ thời gian để hướng dẫn cả cách để làm việc này.

Dù cho bạn chọn cách nào đi nữa thì sau khi lấy dữ liệu từ tên miền đầu tiên, copy dữ liệu cho các tên miền khác bên dưới, hãy nhớ là đừng cho dòng ‘’Header’’ vào. Bằng cách này, bạn sẽ có 1 list liền các dữ liệu từ tất cả dữ liệu chỉ với 1 dòng ‘’ Header’’ chung.

Chú ý quan trọng: Nếu bạn đang phân tích 1 lượng lướn Backlink( trên 50k) thì bạn chỉ nên nhập 1 số lượng hạn chế lúc ban đầu (10-20k)rồi sau đó mới thêm nốt phần còn lại (cũng tầm 10-20k) sau khi đã chèn xong cột tính toán vào bược tiếp theo. Điều này phụ thuộc vào bản Excel của bạn để tránh những lỗi cảnh báo.

Bạn nên nhập tất cả các dữ liệu vào Excel. Đây là tùy bạn nhưng tôi nhận thấy dễ dàng hơn để thực hiện khi cho dữ liệu vào trong 1 bảng. Để thực hiện, bạn cần chọn tất cả các dữ liệu (chỉ vào dữ liệu đầu tiên A1 rồi Ctrl A) sau đó chuyển nó vào bảng (dùng Ctrl L).

Hãy nhớ rằng nếu không có bảng, bạn sẽ phải chỉnh sửa các công thức nhiều đấy.



Bước 3: Lập các công thức cần thiết
Vì chúng ta phải có tất cả các dữ liệu trong Excel nên chúng ta cũng cần lập các công thức tính toàn cần thiết cho bước tiếp theo.

Công thức tính toán đầu tiên đơn giản sẽ chỉ dành cho các dữ liệu cột URL, Target URL chứ không cho các tên miền phụ. Các công thức tính toán này là 1 điều tuyệt vời được trích dẫn từ mục ‘’Excel for Seo’’ của Distilled.

Chúng ta cần tạo ra 2 cột mới để lưu trữ dữ liệu, chúng ta sẽ đặt tên cho cột đầu tiên là ‘’ Source Subdomain’’ và cột thứ 2 là "Target Subdomain’’. Vì chúng ta đã có 1 bảng nên chúng ta chỉ cần nhập tên vào 2 cột liền kề nhau và Excel sẽ tách chúng thành rồi chia vào bảng tự đông.



Công thức thứ nhất là:

Source Subdomain:
=MID([@URL],FIND("://",[@URL])+3,IFERROR(FIND("/",[@URL],9),LEN([@URL])+1)-(FIND("://", [@URL])+3))
Công thức thứ 2 là:
Target Subdomain:
=MID([@[Target URL]],FIND("://",[@[Target URL]])+3,IFERROR(FIND("/",[@[Target URL]],9),LEN([@[Target URL]])+1)-(FIND("://",[@[Target URL]])+3))
Công thức này được hiển thị trong mẫu : ‘’ ://…/’’
Phần IFERROR cho phép bạn có được kết quả đúng của công thức ở nơi mà không có dấu ‘’/’’ kết thúc, giống như trang chủ của URL.

Bạn chỉ cần nhập các dữ liệu đầu tiên của mỗi cột, và Excel sẽ tự động đưa chúng cho toàn bộ cột.

Chú ý quan trọng: Nếu bạn đã chọn các trang tới tên miền phụ thay vì tên miền gốc khi nhập dữ liệu thì bạn sẽ không cần nhập thêm 2 công thức bởi vì bạn chỉ cần có 1 tên miền phụ cho mỗi trang. (ví dụ www. seomoz.org cho Moz, seogadget.co.uk cho SEOgadget, vv.)

Bây giờ, chắc bạn đang phân vân liệu có xảy ra vấn đề gì xảy ra khi chúng ta chỉ sử dụng 1 tên miền phụ ở Target URL. Và Điều này có nghĩa rằng seomoz.org và www.seomoz.org sẽ được tính như các trang web khác nhau...



Để sửa lỗi này, chúng ta phải kéo tên miền gốc thực tế ra khỏi tên miền phụ. Điều này cũng có đôi chút phức tạp bởi vì chúng ta phải phân biệt giữa TLDs (tên miền top đầu) và SLDs (tên miền top 2) bởi vì 1 trong số những đối thủ cạnh tranh của chúng ta là SLDs (SEO gadget) và chúng ta không muốn kết thúc bằng tên miền co.uk thay vì seogadget.co.uk

Chú ý quan trọng: Nếu bạn có Seo Tools cho Excel plugin của Niels Bosma, bạn có thê bỏ qua TLDs và công thức của Target Root Domai và chỉ sử dụng 1 công thức để lấy tên miền gốc. Trong trường hợp này công thức có lẽ nên sử dụng là : =UrlProperty([@[Target Subdomain]]; “domain”). Tuy nhiên nếu bạn muốn sử dụng SLDs của chính mình, (ví dụ: "blogspot.com") , bạn sẽ cần sử dụng các chức năng dưới đây:

Đầu tiên, chúng ta phải liệt kê tất cả TLDs và SLDs chúng ta sẽ phải xử lí trong cột Target URL. Tôi chọn cột Z làm mẫu. List của chúng ta như sau:
.com
.net
.org
.co
.uk



Hãy luôn đặt SDLs dưới TDLs để đảm bảo rằng chúng sẽ bị phát hiện cuối cùng. Nghĩ 1 chút về các quy tắc, các công thức sẽ kiểm tra giúp bạn và sẽ trả về kết quả khi nó nhận thấy sự phù hợp.Ví dụ, nếu một trong những đối thủ cạnh tranh của bạn là một blog lưu trữ trên "blogspot.com.", bạn chỉ cần đặt công thức đó dưới ‘’.com’’ là nó sẽ tự kiểm tra xem đúng không.

TLD
=LOOKUP(2^15,SEARCH($Z$1:$Z$4,[@[Target Subdomain]]),$Z$1:$Z$4)
Giá trị 2^15 giúp cho công thức xác định được sự xuất hiện cuối cùng của TDL trong Target Subdomain. Nếu bạn vẫn chưa hiểu hết được trường hợp này, ví dụ về ‘’test.comparison.org’’ này sẽ giúp bạn hiểu hơn. Bạn muốn bỏ phần ‘’org’’ bởi vì đó rõ ràng là TLD. Tuy nhiên, nếu không có ‘’2^15’’ Excel sẽ không nhận ‘’.comparison’’ và ngừng lại. Vì vậy nó sẽ chọn ‘’.com’’ và như vậy sẽ dẫn đến 1 error.

Dãy $Z$1:$Z$4 dùng để kí hiệu cho các dữ liệu chứa TLD



Bởi vì chúng ta đã có TLD, nên hãy chiếm lấy tên miền gốc thực tế. Để thực hiện điều này, chúng ta cần dùng đến Target Subdomain, nhập mọi dữ liệu sau dấu chấm cuối cùng và áp TLD lạivào để thực hiện. Điều này đồng nghĩa rằng nếu chúng ta có "some.thing.example.com", chúng ta sẽ bỏ TLD, và lấy "some.thing.example", loại bỏ mọi thứ sau dấu chấm cuối cùng tức là chúng ta còn ‘’example’’ sau đó áp dụng TLD vào lại và chúng ta có tên miền gốc‘’example.com’’.

Target Root Domain
=IFERROR(RIGHT([@[Target Subdomain]],LEN([@[Target Subdomain]])-FIND("|",SUBSTITUTE(LEFT([@[Target Subdomain]],LEN([@[Target Subdomain]])-LEN([@TLD])),".","|",LEN(LEFT([@[Target Subdomain]],LEN([@[Target Subdomain]])-LEN([@TLD])))-LEN(SUBSTITUTE(LEFT([@[Target Subdomain]],LEN([@[Target Subdomain]])-LEN([@TLD])),".",""))))),[@[Target Subdomain]])
Vâng, nó hơi dài 1 chút. Tuy nhiên tôi muốn bằng mọi cách phải hiểu hết được công thức này để tránh việc tạo ra những cột không cần thiết. Mục IFERROR được đề cập lúc trước là về trường hợp Target Domain là Root Subdomain , nên kết quả trả về chỉ như vậy. Phần còn lại của công thức vẫn thực hiện chính xác như những gì tôi đã miêu tả bên trên.



Bây giờ chúng ta đã có những tên miền gốc riêng!

Công thức thứ 5 (hoặc 3 đối với những người không sử dụng thêm 2 công thức) tập trung vào kiểm tra xem một tên miền gốc có liên kết tới 1 Target Domain ít nhất 1 lần hay không, vì vậy sau đó bạn có thể biết được có bao nhiêu các đối thủ cạnh tranh của bạn đã lấy liên kết từ nguồn đó của bạn.

Trong bảng chính mà chúng ta thành lập ở bước tiếp theo, công thức này sẽ thực hiện 1 ‘’tính toán đặc biệt’’ về các liên kết gốc theo từng nguồn URL. Và bạn không có công cụ khác nào thành lập công thức này ngoài Excel 2013 đâu.

Tôi đang nói về điều này bởi vì, để tạo ra được 1 ‘’tính toán đặc biệt’’ như vậy chúng ta thực tế chỉ sử dụng 1 trong 3 công thức. 2 trong số chúng có vẻ nhanh hơn công thức thứ 3 này nhưng bạn sẽ nhận thấy 1 số cảnh báo lỗi từ Excel về 1 lượng liên kết quá lớn. Vậy nên tối quyết định dùng công thức thứ 3.

Tạo ra 1 cột liền kề mới được gọi là ‘’Unique Domains’’ và thêm công thức sau:
=IF(COUNTIFS(INDIRECT(ADDRESS(ROW(Table2[#Headers])+1,COLUMN([Source Subdomain]))&":"&ADDRESS(ROW([@[Source Subdomain]]),COLUMN([Source Subdomain]))), [@[Source Subdomain]],INDIRECT(ADDRESS(ROW(Table2[#Headers])+1,COLUMN([Target Root Domain]))&":"&ADDRESS(ROW([@[Target Root Domain]]),COLUMN([Target Root Domain]))), [@[Target Root Domain]])=1,1,0)
COUNTIFS có chức năng đếm số lần mà 1 Source Subdomain trùng với Target Root Domain. Còn IF xác định sự liên kết đầu tiên của chúng và trả về các giá trị 1 và 0 ( có nghĩa là Có, chúng đã liên kết với nhau ít nhất 1 lần)

Công thức có vẻ rất dài nhưng nó chỉ tương đương với : =IF(COUNTIFS($O$2:$O2,$O2,$R$2:$R2,$R2)=1,1,0)
Trong trường hợp này, cột 0 là Source Subdomain và cột R là Target Root Subdomain, còn 2 là số hàng nơi công thức trên được hiển thị.

Tôi đã chọn công thức dào hơn vậy nên nó có thể được áp dụng mà không cần xác định số hàng và số cột để khiến nó hoạt động được. Điều này lí giải tại sao tôi đã sử dụng chức năng INDIRECT và ADDRESS.

Nhớ rằng nếu bạn không sử dụng công thức TLD/ Root Domain thì bạn sẽ phải dùng Target Subdomain thay cho Target Root Domain.

Tuy nhiên, hàm COUNTIF lại không làm việc trong Excel 2003 vậy nên chúng ta cần sử dụng công thức khác cho vấn đề này (dùng bản SUMPRODUCT)

Công thức cuối cùng thì đơn giản hơn, nhưng giúp chúng ta kiểm tra xem các liên kết có hướng tới chúng ta hay không. Tạo ra 1 cột liền kề tên là ‘’LINK TO US’’ và sau đó nhập công thức :

LINK TO US
=IF([@[Target Root Domain]]="seomoz.org",1,0)



Công thức này là 1 phép điều kiện cơ bản, nó sẽ trả về 1 nếu đó là liên kết gốc của bạn và trả về 0 nếu là đối thủ cạnh tranh của bạn.

Nhớ rằng nếu bạn không sử dụng công thức TLD/Root Domain, bạn sẽ phải sử dụng Target Subdomain thay vì Target Root Domain ( ví dụ cho trường hợp này: [@[Target Subdomain]]=’’www.seomoz.org’’)

Bước 4: Xây dựng bảng Pivot (bảng chính)
Vì chúng ta đã có bảng dữ liệu backlink nên 2 bước cuối này sẽ hoàn toàn dễ dàng thôi.
Tạo một trang mới tên ‘’Pivot Table’’- nơi mà bạn sẽ dùng để phân tích dữ liệu



Quá trình tạo bảng như sau:
Nhấp Insert tab => nhấn nút Pivot Table => nhập tên bảng chứa dữ liệu backlink=>OK



Bạn sẽ có 1 bảng trống với 1 thanh dọc Field List. Đây là cách chúng ta định dạng nó:
Kéo U nique Domains, Link To Us hay bất cứ thông số nào cần thiết tới hộp Values sau đó tất cả mục này sẽ được thêm vào tự động. Với các thông số chúng ta cần thực hiện: Click ‘’ Sum of Domain Authority’’ => Value Field Settings => chọn Average instead of Sum => OK



Việc định dạng các mục trên nên diễn ra như này:



Sau đó, bởi vì dữ liệu bây giờ đã được mở rộng sang dạng khác và chúng ta không thể nhìn thấy chính xác nên chúng ta cần sử dụng tới Source Subdomain. Để làm điều này, chúng ta cần click vào 1 trong những tên miền phụ gốc ở bảng Pivot Table=> đảm bảo rằng bạn đang ở Menu => click vào Collapse Entire Field.

Click vào đây để xem ảnh gốc.


Bước 5: Phân loại nó và bạn đã hoàn thành !
Bởi vì chúng ta đã có mọi thứ chúng ta cần ở bảng Pivot Table, chúng ta chỉ cần phân loại dữ liệu. Đầu tiên, chúng ta cần lấy được các liên kết của các đối thủ cạnh tranh nên chúng ta cần lọc các Source Subdomains mà liến kết tới chúng ta.
Để làm điều này, click vào Row Labels rồi thả => Value Filters -> Equals... -> trong cửa sổ mới mà bạn mở ta chọn "Sum of Link To Us" và nhấn 0 vào mục Value => OK

Click vào đây để xem ảnh gốc.


Cơ bản là bạn muốn xem các trang mà liên kết tới hầu hết các đối thủ cạnh tranh của bạn như tôi đã đề cập nhưng cũng có khả năng nhưng trang đó cũng liên kết tới cả bạn.

Để phân loại nó, click Row Labels rồi thả => More Sort Options => chọn Descending (Z to A) by => Sum of Unique Domains => OK





Ở đây chúng ta có một Bảng Pivot với các tên miền mà liến kết tới các đối thủ cạnh tranh của chúng ta rồi. Tất nhiên bạn có thể phân loại nó bằng Domain Authority. Bản cuối cùng sẽ trông như này:

Click vào đây để xem ảnh gốc.


Lưu ý: Trước khi lưu các file, để tiết kiệm thời gian để mở ra cũng như giảm size, chúng ta có thể thay tất cả các công thưc bằng giá trị của chúng để Excel không tính toán lại được chúng nữa. Bước này được kết thúc bằng việc chọn tất cả dữ liệu ở bảng (Ctrl A)=> copy (Ctrl C) => chỉ paste các giá trị mà thôi. (Paste Values)

Những cải tiến trong tương lai
Có 1 vài thứ mà tôi nghĩ rằng có thể được thêm vào công cụ này:
- Khả năng để phân loại bằng Unique Domain đầu tiên, sau đó mới bằng 1 hay vài thông số
- Khả năng lọc bằng các thông số nhỏ/lớn hơn
- Khả năng tạo lại các bảng Pivot để xem thêm nhiều cơ hội hơn: có nghĩa là bạn có thể dùng Source Subdomain thay vì URL Field.

Mẫu và các hướng dẫn sử dụng
Như đã hứa, tôi sẽ gắn vào 1 mấu bao gồm tất cả các công thức cần thiết và Bảng Pivot để bạn chỉ cần add vào dữ liệu liên kết của bạn.

Tôi quyết định tạo 2 file tách biệt sau:
vertify-link-intersect-sample-SUBDOMAIN.xlsx- file này có thể sử dụng khi bạn có dữ liệu backlink từ 1 tên miền phụ cho mỗi website ( cả của bạn và đối thủ cạnh tranh) và các backlink hướng tới các trang của tên miền phụ đó.

vertify-link-intersect-sample-ROOTDOMAIN.xlsx- file này có thể được sử dụng khi khi bạn sử dụng dữ liệu backlink tới các trang của tên miền gốc ít nhất 1 lần 1 website. Trong trường hợp này sẽ có thêm 2 cột để trích dẫn các tên miền gốc, điều này đồng nghĩa rằng bạn có thể xác định được list TLD trong trang Configuration

Click vào đây để xem ảnh gốc.